De: "isabelle" <amu.sherb@videotron.net>
Objet: Re: Imprimer page courante seulement
Date : jeudi 15 f&eacute;vrier 2001 19:30

Bonjour Sophie

si tu as la Function NumPage de Laurent Longre, 

Sub imprime_la_page_courante()
Dim NoDePage
NoDePage = NumPage(ActiveCell)
ActiveWindow.SelectedSheets.PrintOut From:=NoDePage, To:=NoDePage, Copies:=1
End Sub

Function NumPage(Cellule As Range) As Integer
  Dim VPC As Integer, HPC As Integer
  Dim VPB As VPageBreak, HPB As HPageBreak
  Dim Wksht As Worksheet
  Dim Col As Integer, Ligne As Long
  set Wksht = Cellule.Worksheet
  Ligne = Cellule.Row
  Col = Cellule.Column
  If Wksht.Pagesetup.Order = xlDownThenOver Then
    HPC = Wksht.HPageBreaks.Count + 1
    VPC = 1
  Else
    VPC = Wksht.VPageBreaks.Count + 1
    HPC = 1
  End If
  NumPage = 1
  For Each VPB In Wksht.VPageBreaks
    If VPB.Location.Column > Col Then Exit For
    NumPage = NumPage + HPC
  Next VPB
  For Each HPB In Wksht.HPageBreaks
    If HPB.Location.Row > Ligne Then Exit For
    NumPage = NumPage + VPC
  Next HPB
End Function

isabelle

Sophie a &eacute;crit :
> 
> Bonjour,
> 
> Existe-t-il une facon ou une macro pour imprimer la page courante seulement
> (un peu comme dans Word lorsqu'on choisit Imprimer, page courante) ?
> 
> Merci de votre aide
> 
> Sophie 