De: "popi" <popi@infonie.fr>
Objet: Re: Macro : comment faire afficher la ligne "n" en haut d'&eacute;cran
Date : vendredi 15 juin 2001 15:00

Salut Jean-Pierre,
ceci devrait correspondre à ce que tu cherches (je ne sais pas qui en est
l'auteur)
Sub synchro_onglets()
'   Duplicates the active sheet's active cell upperleft cell
'   Across all worksheets
    If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub
    Dim UserSheet As Worksheet, sht As Worksheet
    Dim TopRow As Long, LeftCol As Integer
    Dim UserSel As String

    Application.ScreenUpdating = False

'   Remember the current sheet
    set UserSheet = ActiveSheet

'   Store info from the active sheet
    TopRow = ActiveWindow.ScrollRow
    LeftCol = ActiveWindow.ScrollColumn
    UserSel = ActiveWindow.RangeSelection.Address

'   Loop through the worksheets
    For Each sht In ActiveWorkbook.Worksheets
        If sht.Visible Then 'skip hidden sheets
            sht.Activate
            Range(UserSel).Select
            ActiveWindow.ScrollRow = TopRow
            ActiveWindow.ScrollColumn = LeftCol
        End If
    Next sht

'   Restore the original position
    UserSheet.Activate
    Application.ScreenUpdating = True
End Sub
@+
"Jean-Pierre" <jp.passimourt@kompass-france.com> a &eacute;crit dans le message
news: 733301c0f598$90e82160$b1e62ecf@tkmsftngxa04...
Bonjour,

J'ai enregistr&eacute; une macro qui me permet de passer d'une feuille à l'autre,
n&eacute;anmoins, je n'arrive pas à positionner une ligne "n" en haut de page, que
faut-
il rajouter à ma macro pour obtenir ce r&eacute;sultat.

Ci dessous la macro que j'utilise :

Sheets("feuil2").Select
ActiveCell.Offset(147, 0).Rows("1:1").EntireRow.Select
End Sub

(je souhaite que la ligne 147 soit la première affich&eacute; sur ma page)


Merci de votre aide

Jean-Pierre

 